@echo off
color 1f
title ESD解密工具
echo 欢迎使用ESD decrypter汉化版(ESD解密工具)
echo ===============================================
echo 您可以使用此工具解密一个加密的 ESD 文件或者使用
echo 它解密 ESD 文件并生成一个可引导的 ISO 文件或者 WIM 文件。
echo 要开始，请你按下任意键。
pause
@echo off
%windir%\system32\reg.exe query "HKU\S-1-5-19" 1>nul 2>nul || (
echo      -------
echo  *** 警告    ***
echo      -------
echo.
echo.
echo 请以管理员权限运行这个程序。
echo ____________________________________________________________________________
echo.
echo 这个脚本请求管理员模式。
echo.
echo 要以管理员权限运行，请右击这个 CMD 命令脚本，然后单击“以管理员身份运行”。
echo.
echo.
echo.
echo 请按任意键退出。
pause >nul
goto :eof
)

for /f "tokens=6 delims=[]. " %%G in ('ver') do set winbuild=%%G
if %winbuild% GEQ 9600 if exist %windir%\servicing\Editions\WimBootConfig.ini (
SET DISMRoot=%windir%\system32\dism.exe
goto :prepare
)

SET regKeyPathFound=1
SET wowRegKeyPathFound=1
REG QUERY "HKLM\Software\Wow6432Node\Microsoft\Windows Kits\Installed Roots" /v KitsRoot81 1>NUL 2>NUL || SET wowRegKeyPathFound=0
REG QUERY "HKLM\Software\Microsoft\Windows Kits\Installed Roots" /v KitsRoot81 1>NUL 2>NUL || SET regKeyPathFound=0
if %wowRegKeyPathFound% EQU 0 (
  if %regKeyPathFound% EQU 0 (
    goto :skip
  ) else (
    SET regKeyPath=HKLM\Software\Microsoft\Windows Kits\Installed Roots
  )
) else (
    SET regKeyPath=HKLM\Software\Wow6432Node\Microsoft\Windows Kits\Installed Roots
)
FOR /F "skip=2 tokens=2*" %%i IN ('REG QUERY "%regKeyPath%" /v KitsRoot81') DO (SET KitsRoot=%%j)
SET DandIRoot=%KitsRoot%Assessment and Deployment Kit\Deployment Tools
cd /d "%DandIRoot%\%PROCESSOR_ARCHITECTURE%\DISM"
for /f "tokens=5 delims=:." %%G in ('dism /English /? ^| find /i "Version"') do set dismver=%%G
if %dismver% LSS 17029 goto :skip
cd /d "%~dp0"
SET DISMRoot=%DandIRoot%\%PROCESSOR_ARCHITECTURE%\DISM\dism.exe
goto :prepare

:skip
SET DISMRoot=%~dp0dism\dism.exe

:prepare
if not exist "%~dp0dism\dism.exe" goto :eof
color 1f
cd /d "%~dp0"
setlocal EnableDelayedExpansion
SET ENCRYPTEDESD=
SET ERRORTEMP=

if "%1"=="" (
set _esd=0
if exist "*.esd" (for /f %%i in ('dir /b "*.esd"') do (call set /a _esd+=1))
if !_esd! equ 0 (
  echo.
  echo ===============================================================================
  echo 错误：没有特别的 ESD 文件或者文件损坏。请检查文件的存放情况。
  echo ===============================================================================
  echo.
  echo 请你按任意键退出。
  pause >nul
  goto :eof
  )
if !_esd! gtr 1 goto :prompt
for /f %%i in ('dir /b "*.esd"') do set ENCRYPTEDESD=%%i
) else (
SET ENCRYPTEDESD=%~1
)
goto :check

:prompt
echo.
echo ===============================================================================
echo 在当前目录中发现多于1个 ESD 文件。
echo 键入 / Paste name of the desired ESD file to process
echo ===============================================================================
echo.
set /p ENCRYPTEDESD=
if [%ENCRYPTEDESD%]==[] goto :QUIT

:check
dism\dism.exe /get-wiminfo /wimfile:%ENCRYPTEDESD% 1>nul 2>nul || (
echo.
echo ===============================================================================
echo 错误：特别的 ESD 文件损坏或者已经被损坏。
echo ===============================================================================
echo.
echo 请你按任意键退出程序。
pause >nul
goto :eof
)

dism\dism.exe /english /get-wiminfo /wimfile:%ENCRYPTEDESD% /index:4 | find /i "Architecture" >nul
IF %ERRORLEVEL% NEQ 0 (
echo.
echo 正在读取文件时发生错误。
echo.
echo 请你按任意键退出程序。
pause >nul
goto :eof
)
for /f "tokens=2 delims=: " %%i in ('dism\dism.exe /english /get-wiminfo /wimfile:%ENCRYPTEDESD% /index:4 ^| find /i "Architecture"') do set arch=%%i

dism\dism.exe /english /get-wiminfo /wimfile:%ENCRYPTEDESD% /index:4 | find /i "Edition" >nul
IF %ERRORLEVEL% NEQ 0 (
echo.
echo 正在读取版本号时发生错误。
echo.
echo 请你按任意键退出。
pause >nul
goto :eof
)
for /f "tokens=2 delims=: " %%i in ('dism\dism.exe /english /get-wiminfo /wimfile:%ENCRYPTEDESD% /index:4 ^| find /i "Edition"') do set editionid=%%i

dism\dism.exe /english /get-wiminfo /wimfile:%ENCRYPTEDESD% /index:4 | find /i "Default" >nul
IF %ERRORLEVEL% NEQ 0 (
echo.
echo 正在读取安装包的语言时发生错误。
echo.
echo 请你按任意键退出。
pause >nul
goto :eof
)
for /f "tokens=1" %%i in ('dism\dism.exe /english /get-wiminfo /wimfile:%ENCRYPTEDESD% /index:4 ^| find /i "Default"') do set langid=%%i

dism\dism.exe /english /get-wiminfo /wimfile:%ENCRYPTEDESD% /index:4 | find /i "Version" >nul
IF %ERRORLEVEL% NEQ 0 (
echo.
echo There is a problem reading the index version.
echo.
echo Press any key to exit.
pause >nul
goto :eof
)
for /f "skip=1 tokens=4 delims=:." %%G in ('dism\dism.exe /english /get-wiminfo /wimfile:%ENCRYPTEDESD% /index:4 ^| find /i "Version"') do set build=%%G

dism\dism.exe /english /get-wiminfo /wimfile:%ENCRYPTEDESD% /index:4 | find /i "ServicePack Build" >nul
IF %ERRORLEVEL% NEQ 0 (
echo.
echo There is a problem reading the index build.
echo.
echo Press any key to exit.
pause >nul
goto :eof
)
for /f "tokens=3 delims=: " %%i in ('dism\dism.exe /english /get-wiminfo /wimfile:%ENCRYPTEDESD% /index:4 ^| find /i "ServicePack Build"') do set svcbuild=%%i

set tag=IR3
if %svcbuild% EQU 17056 set tag=IR4
if /i "%arch%"=="x86" set arch=X86
if /i "%arch%"=="x64" set arch=X64
if /i "%langid%"=="ar-sa" set langid=AR-SA
if /i "%langid%"=="en-gb" set langid=EN-GB
if /i "%langid%"=="en-us" set langid=EN-US
if /i "%langid%"=="es-es" set langid=ES-ES
if /i "%langid%"=="fr-fr" set langid=FR-FR
if /i "%langid%"=="pt-br" set langid=PT-BR
if /i "%langid%"=="pt-pt" set langid=PT-PT
if /i "%langid%"=="ru-ru" set langid=RU-RU
if /i "%langid%"=="th-th" set langid=TH-TH
if /i "%langid%"=="tr-tr" set langid=TR-TR
if /i "%langid%"=="bg-bg" set langid=BG-BG
if /i "%langid%"=="cs-cz" set langid=CS-CZ
if /i "%langid%"=="da-dk" set langid=DA-DK
if /i "%langid%"=="de-de" set langid=DE-DE
if /i "%langid%"=="el-gr" set langid=EL-GR
if /i "%langid%"=="et-ee" set langid=ET-EE
if /i "%langid%"=="fi-fi" set langid=FI-FI
if /i "%langid%"=="he-il" set langid=HE-IL
if /i "%langid%"=="hr-hr" set langid=HR-HR
if /i "%langid%"=="hu-hu" set langid=HU-HU
if /i "%langid%"=="it-it" set langid=IT-IT
if /i "%langid%"=="lt-lt" set langid=LT-LT
if /i "%langid%"=="lv-lv" set langid=LV-LV
if /i "%langid%"=="nb-no" set langid=NB-NO
if /i "%langid%"=="nl-nl" set langid=NL-NL
if /i "%langid%"=="pl-pl" set langid=PL-PL
if /i "%langid%"=="ro-ro" set langid=RO-RO
if /i "%langid%"=="sk-sk" set langid=SK-SK
if /i "%langid%"=="sl-si" set langid=SL-SI
if /i "%langid%"=="sr-latn-rs" set langid=SR-LATN-RS
if /i "%langid%"=="sv-se" set langid=SV-SE
if /i "%langid%"=="ja-jp" set langid=JA-JP
if /i "%langid%"=="ko-kr" set langid=KO-KR
if /i "%langid%"=="uk-ua" set langid=UK-UA
if /i "%langid%"=="zh-cn" set langid=ZH-CN
if /i "%langid%"=="zh-hk" set langid=ZH-HK
if /i "%langid%"=="zh-tw" set langid=ZH-TW
set DVDLABEL=%tag%_CCSA_%arch%FRER_%langid%_DV9
if "%editionid%"=="CoreSingleLanguage" set DVDLABEL=%tag%_CSLA_%arch%FRER_%langid%_DV9
if "%editionid%"=="ProfessionalWMC" set DVDLABEL=%tag%_CPWMCA_%arch%FRER_%langid%_DV9
if "%editionid%"=="CoreCountrySpecific" set DVDLABEL=%tag%_CCHA_%arch%FRER_%langid%_DV9
if "%editionid%"=="Core" set DVDLABEL=%tag%_CCOA_%arch%FRER_%langid%_DV9
if "%editionid%"=="CoreN" set DVDLABEL=%tag%_CCNA_%arch%FRER_%langid%_DV9
if "%editionid%"=="Professional" set DVDLABEL=%tag%_CPRA_%arch%FRER_%langid%_DV9
if "%editionid%"=="ProfessionalN" set DVDLABEL=%tag%_CPRNA_%arch%FRER_%langid%_DV9
if "%editionid%"=="CoreConnected" set DVDLABEL=%tag%_CCONA_%arch%FRER_%langid%_DV9
if "%editionid%"=="CoreConnectedN" set DVDLABEL=%tag%_CCONNA_%arch%FRER_%langid%_DV9
if "%editionid%"=="CoreConnectedSingleLanguage" set DVDLABEL=%tag%_CCSLA_%arch%FRER_%langid%_DV9
if "%editionid%"=="CoreConnectedCountrySpecific" set DVDLABEL=%tag%_CCCHA_%arch%FRER_%langid%_DV9
if "%editionid%"=="ProfessionalStudent" set DVDLABEL=%tag%_CPSA_%arch%FRER_%langid%_DV9
if "%editionid%"=="ProfessionalStudentN" set DVDLABEL=%tag%_CPSNA_%arch%FRER_%langid%_DV9
if %build% GTR 9600 if "%editionid%"=="Professional" set DVDLABEL=JM1_CPRA_%arch%FRER_%langid%_DV9
if %build% GTR 9600 if "%editionid%"=="Enterprise" set DVDLABEL=JM1_CENA_%arch%FREV_%langid%_DV9

:MAINMENU
cls
echo ===============================================================================
echo.                          Lesita ESD 转换脚本 QQ316433938 远景 Lesita
echo ===============================================================================
echo.                   1 - 转换一个名为  install.esd
echo.                   2 - 转换一个名为  install.wim
echo.                   3 - 建立一个带有 install.esd 的完整 ISO
echo.                   4 - 建立一个带有 install.wim 的完整 ISO
echo ===============================================================================
echo.                            按 0 键退出程序
echo ===============================================================================

choice /c 12340 /n /m "选择一个选项，或者按 0 键退出程序。 "
SET ERRORTEMP=%ERRORLEVEL%
IF %ERRORTEMP%==1 GOTO :Selection1
IF %ERRORTEMP%==2 GOTO :Selection2
IF %ERRORTEMP%==3 GOTO :Selection3
IF %ERRORTEMP%==4 GOTO :Selection4
IF %ERRORTEMP%==5 GOTO :QUIT
GOTO :MAINMENU

:Selection1
cls
IF EXIST "%CD%\install.esd" (
echo.
echo ===============================================================================
echo.  在当前的文件夹中已经存在一个 install.esd 文件。
echo ===============================================================================
echo.
echo 请你按任意键退出程序。
pause >nul
GOTO :QUIT
)
echo.
CALL :DECRYPT
echo ===============================================================================
echo 正在将 4 号 ESD 区段转换成一个新的 install.wim 文件。
echo ===============================================================================
"%DISMRoot%" /export-image /sourceimagefile:"%ENCRYPTEDESD%" /Sourceindex:4 /destinationimagefile:install.esd /compress:recovery /checkintegrity
SET ERRORTEMP=%ERRORLEVEL%
IF %ERRORTEMP% NEQ 0 (echo.&echo Errors were reported during dism export.) else (echo.&echo Done.)
echo.
echo Press any key to exit.
pause >nul
GOTO :QUIT

:Selection2
cls
IF EXIST "%CD%\install.wim" (
echo.
echo ===============================================================================
echo.  在当前的文件夹中已经存在一个 install.wim 文件。
echo ===============================================================================
echo.
echo Press any key to exit.
pause >nul
GOTO :QUIT
)
echo.
CALL :DECRYPT
echo ===============================================================================
echo 正在将 4 号 ESD 区段转换成一个新的 install.wim 文件。
echo ===============================================================================
mkdir temp
"%DISMRoot%" /Quiet /Capture-Image /ImageFile:install.wim /CaptureDir:.\temp /Name:container /Compress:max /CheckIntegrity
rmdir /s /q temp
"%DISMRoot%" /Export-Image /SourceImageFile:"%ENCRYPTEDESD%" /SourceIndex:4 /DestinationImageFile:install.wim /compress:recovery /CheckIntegrity
SET ERRORTEMP=%ERRORLEVEL%
IF %ERRORTEMP% NEQ 0 (echo.&echo Errors were reported during dism export.&PAUSE&GOTO :QUIT)
"%DISMRoot%" /Quiet /Delete-Image /ImageFile:install.wim /Index:1 /CheckIntegrity
if "%editionid%"=="ProfessionalWMC" (
echo.
echo ===============================================================================
echo 正在生成 WMC 标识。
echo ===============================================================================
echo.
pushd .\dism
wimlib-imagex.exe update "%~dp0install.wim" 1 --check < wim-update.txt 1>nul 2>nul
popd
echo Done.
)
echo.
echo Press any key to exit.
pause >nul
GOTO :QUIT

:Selection3
cls
echo.
CALL :DECRYPT
echo ===============================================================================
echo 正在创建 ISO 文件标识。
echo ===============================================================================
IF EXIST ISOFOLDER\ rmdir /s /q ISOFOLDER\
mkdir ISOFOLDER
"%DISMRoot%" /apply-image /imagefile:"%ENCRYPTEDESD%" /index:1 /applydir:ISOFOLDER\
SET ERRORTEMP=%ERRORLEVEL%
IF %ERRORTEMP% NEQ 0 (echo.&echo Errors were reported during dism apply.&PAUSE&GOTO :QUIT)
del ISOFOLDER\MediaMeta.xml
echo.
echo ===============================================================================
echo 正在将 2 号 ESD 文件转换成新的 boot.wim
echo ===============================================================================
mkdir temp
"%DISMRoot%" /Quiet /Capture-Image /ImageFile:ISOFOLDER\sources\boot.wim /CaptureDir:.\temp /Name:container /Compress:max
rmdir /s /q temp
"%DISMRoot%" /Export-Image /SourceImageFile:"%ENCRYPTEDESD%" /SourceIndex:2 /DestinationImageFile:ISOFOLDER\sources\boot.wim /compress:recovery /Bootable
SET ERRORTEMP=%ERRORLEVEL%
IF %ERRORTEMP% NEQ 0 (echo.&echo Errors were reported during dism export.&PAUSE&GOTO :QUIT)
"%DISMRoot%" /Quiet /Delete-Image /ImageFile:ISOFOLDER\sources\boot.wim /Index:1
echo.
echo ===============================================================================
echo 正在将 3 号 ESD 文件转换成新的 boot.wim
echo ===============================================================================
"%DISMRoot%" /Export-Image /SourceImageFile:"%ENCRYPTEDESD%" /SourceIndex:3 /DestinationImageFile:ISOFOLDER\sources\boot.wim /compress:recovery /Bootable
SET ERRORTEMP=%ERRORLEVEL%
IF %ERRORTEMP% NEQ 0 (echo.&echo Errors were reported during dism export.&PAUSE&GOTO :QUIT)
echo.
echo ===============================================================================
echo 正在将 4 号 ESD 文件转换成新的 install.esd
echo ===============================================================================
"%DISMRoot%" /export-image /sourceimagefile:"%ENCRYPTEDESD%" /Sourceindex:4 /destinationimagefile:ISOFOLDER\sources\install.esd /compress:recovery /checkintegrity
SET ERRORTEMP=%ERRORLEVEL%
IF %ERRORTEMP% NEQ 0 (echo.&echo Errors were reported during dism export.&PAUSE&GOTO :QUIT)
echo.
echo ===============================================================================
echo 正在创建 ei.cfg 文件（标识系统版本以及安装参数，如零售版/批量版等。）
echo ===============================================================================
echo.
echo [EditionID] >ISOFOLDER\sources\EI.CFG
echo %editionid% >>ISOFOLDER\sources\EI.CFG
echo. >>ISOFOLDER\sources\EI.CFG
echo [Channel] >>ISOFOLDER\sources\EI.CFG
echo Retail >>ISOFOLDER\sources\EI.CFG
echo. >>ISOFOLDER\sources\EI.CFG
echo [VL] >>ISOFOLDER\sources\EI.CFG
echo 0 >>ISOFOLDER\sources\EI.CFG
echo.
echo ===============================================================================
echo 正在建立 ISO 文件。
echo ===============================================================================
dism\oscdimg.exe -bootdata:2#p0,e,b"ISOFOLDER\boot\etfsboot.com"#pEF,e,b"ISOFOLDER\efi\Microsoft\boot\efisys.bin" ^
-o -h -m -u2 -udfver102 ^
-t09/24/2014,09:20:28 -g ^
-l%DVDLABEL% ^
ISOFOLDER ^
%DVDLABEL%.iso
SET ERRORTEMP=%ERRORLEVEL%
IF %ERRORTEMP% NEQ 0 (echo.&echo Errors were reported during ISO creation.)
echo.
echo Press any key to exit.
pause >nul
GOTO :QUIT

:Selection4
cls
echo.
CALL :DECRYPT
echo ===============================================================================
echo 正在布局 ISO 文件
echo ===============================================================================
IF EXIST ISOFOLDER\ rmdir /s /q ISOFOLDER\
mkdir ISOFOLDER
"%DISMRoot%" /apply-image /imagefile:"%ENCRYPTEDESD%" /index:1 /applydir:ISOFOLDER\
SET ERRORTEMP=%ERRORLEVEL%
IF %ERRORTEMP% NEQ 0 (echo.&echo Errors were reported during dism apply.&PAUSE&GOTO :QUIT)
del ISOFOLDER\MediaMeta.xml
echo.
echo ===============================================================================
echo 正在将 2 号 ESD 文件转换成新的 boot.wim 文件
echo ===============================================================================
mkdir temp
"%DISMRoot%" /Quiet /Capture-Image /ImageFile:ISOFOLDER\sources\boot.wim /CaptureDir:.\temp /Name:container /Compress:max
rmdir /s /q temp
"%DISMRoot%" /Export-Image /SourceImageFile:"%ENCRYPTEDESD%" /SourceIndex:2 /DestinationImageFile:ISOFOLDER\sources\boot.wim /compress:recovery /Bootable
SET ERRORTEMP=%ERRORLEVEL%
IF %ERRORTEMP% NEQ 0 (echo.&echo Errors were reported during dism export.&PAUSE&GOTO :QUIT)
"%DISMRoot%" /Quiet /Delete-Image /ImageFile:ISOFOLDER\sources\boot.wim /Index:1
echo.
echo ===============================================================================
echo 正在将 3 号 ESD 文件转换成新的 boot.wim 文件
echo ===============================================================================
"%DISMRoot%" /Export-Image /SourceImageFile:"%ENCRYPTEDESD%" /SourceIndex:3 /DestinationImageFile:ISOFOLDER\sources\boot.wim /compress:recovery /Bootable
SET ERRORTEMP=%ERRORLEVEL%
IF %ERRORTEMP% NEQ 0 (echo.&echo Errors were reported during dism export.&PAUSE&GOTO :QUIT)
echo.
echo ===============================================================================
echo 正在将 4 号 ESD 文件转换成新的 install.wim 文件
echo ===============================================================================
mkdir temp
"%DISMRoot%" /Quiet /Capture-Image /ImageFile:ISOFOLDER\sources\install.wim /CaptureDir:.\temp /Name:container /Compress:max /CheckIntegrity
rmdir /s /q temp
"%DISMRoot%" /Export-Image /SourceImageFile:"%ENCRYPTEDESD%" /SourceIndex:4 /DestinationImageFile:ISOFOLDER\sources\install.wim /compress:recovery /CheckIntegrity
SET ERRORTEMP=%ERRORLEVEL%
IF %ERRORTEMP% NEQ 0 (echo.&echo Errors were reported during dism export.&PAUSE&GOTO :QUIT)
"%DISMRoot%" /Quiet /Delete-Image /ImageFile:ISOFOLDER\sources\install.wim /Index:1 /CheckIntegrity
if "%editionid%"=="ProfessionalWMC" (
echo.
echo ===============================================================================
echo 正在综合主要的 WMC 令牌
echo ===============================================================================
echo.
pushd .\dism
wimlib-imagex.exe update "%~dp0ISOFOLDER\sources\install.wim" 1 --check < wim-update.txt 1>nul 2>nul
popd
)
echo.
echo ===============================================================================
echo 正在建立（生成）可引导的 ISO 文件
echo ===============================================================================
dism\oscdimg.exe -bootdata:2#p0,e,b"ISOFOLDER\boot\etfsboot.com"#pEF,e,b"ISOFOLDER\efi\Microsoft\boot\efisys.bin" ^
-o -h -m -u2 -udfver102 ^
-t09/24/2014,09:20:28 -g ^
-l%DVDLABEL% ^
ISOFOLDER ^
%DVDLABEL%.iso
SET ERRORTEMP=%ERRORLEVEL%
IF %ERRORTEMP% NEQ 0 (echo.&echo Errors were reported during ISO creation.)
echo.
echo 请你按任意键退出。
pause >nul
GOTO :QUIT

:DECRYPT
if not exist %ENCRYPTEDESD%.bak (
echo 正在备份原来的 ESD 文件。
copy %ENCRYPTEDESD% %ENCRYPTEDESD%.bak >nul
)
echo.
echo 正在运行转换程序dism
echo.
if %build% EQU 9600 (
dism\esddecrypt.exe %ENCRYPTEDESD%
if %ERRORLEVEL% EQU 0 exit /b
)
if %build% GTR 9600 (
dism\esddecrypt.exe %ENCRYPTEDESD% BwIAAACkAABSU0EyAAgAAAEAAQA5WQn9lTT4Ci679UcfZW6y8GkbeGTN9bKbgjnigtWmb7pPkifbr3ihmmtJ1ZWJmZCyDyeRNHwHDieOiM8zfgRJr575RKQI8yWi6wNAZVhUZDzKlch4BgABut2lcjZRT5o/Iyotd0tKW7Np1ur8D/HawdmHXdhN42hjg7PKNfvbgXICNNK+uschVzA39HWejEowO5ppaXBObLpN28Ipun3+s0xPNePHNVKD/4azFGd11ZZWmoh3NpnZXBGW3Jk2fn6hmrQ434Mrw4qdpIfTqh/d0aWGE7CseZPYR0F9Gd6DWyXn6JzkvPBPRNtdU7SK5Xeh+pDmTnme5av3c1XNBka2hScgqAT/BOAwaIvufA6QZXccHkeHnOVO/XHEi339OT0FJLNWearerYzfHtHh6D8+d7fIdHBsgMCMd/O2suhNVBWsipzA8UPnhy4+4uPAhoV7fqaYjPbE0fUTXT82SUG11W4tjs8+kTflzwX1qoNezfLdG6++h7LJSGJNPe2QfsQlB8NxLTReIHsyW5Fv5Q0LZH/Z5tJsOeu0P39z9k/oW30TGHIVnipOkdfA1PREFFwDWJ7MKsTQkW2ikSo9Y1HbUhIAb2xI9M28GAxGxdaPa69vAepfqiPOfEFOiZcUhVkLs6vv8GVOsLRMHFalKhwNi6bWX32R76OKmRHLPPl47dkHCBy/nBVSLaVyUo25gEX3pVgGDpoiHOTzeq1qvPdguBMXHtgvpvEMTBEMDFpp1hMqWkNcapPA25oGQmJr5LouRsfaHXe52LoJpniCA/Lf7cFSCbx+Wkh1bl/4uepz45bZGpjde4WvPnKPBOsi+EZ30lYi0mfKGBQ7HS6RE9iQSbOJYZ2djnY+ok8VkGrXU28l1kQParu3mnXOcQdviIJhtH6nor3GjXYbMml40/b3lGPn6qPjf0UW9glD2apdQMyTTxO2YzLlpiW96d5SwsPTDfP83YTZUZd6Er4cvmlb7G4qidlF7xIdVzzmGx5PPAuv6oLzMf3qFHKgo8nGC3ZcHfTsHz62eTvDFfCxuqTSbZYby+SraGvez3gZSKnbmvkfaBumgMPULGjsPC0FGMf1PXzxHQ3Y5chnpxYXF86h9NRRf9efeByhj3cS1AQGNidgIfo1l0CdNDtWegcZC/0U8+0O/lMGUnemt8a+Zl6jb+XHB9czxWjfetE3KcLXlfXrIBMM7Ve3JNEU1dL01vZ7THJXYWS6mIvGnOK+nW4GxsgReW8an5HlE1qF3O0r0vmpttZ6tK0NjxZFrUIVJwE+X/rJrRIS7eJJsgLoI4HD37AMcQ3rGY4/mnR7JitqNj4TNq+P/XNNl7wkjmRLOruLrOdShKON1ZvmaZ9BKUYI02FjxRntO8MPOrR2ImdRpTp+1rGtLlWWe0MxmPOkIQIsPKocIeitjWXIgNErcdzulagizd+cmcf2PPOyNkOd7yVv1xxxLy2ePYsHdGaYxIgM0xJ+NNrNpLz9/3W2quhEt4JL6jIhnIuvIUd67SQLwf7qy2jS3lLwbkBqPJpalAE=
if %ERRORLEVEL% EQU 0 exit /b
)
echo.
echo 在转换过程中出错。
pause >nul
GOTO :QUIT

:QUIT
IF EXIST ISOFOLDER\ rmdir /s /q ISOFOLDER\
IF EXIST %ENCRYPTEDESD%.bak (
del /f /q %ENCRYPTEDESD% >nul 2>&1
ren %ENCRYPTEDESD%.bak %ENCRYPTEDESD%
)
goto :eof